Varian DEPT

Processing Varian DEPT Data

Varian's automated DEPT pulse program generates an arrayed experiment with 4 slices, acquired with phase of the last pulse equal to 45, 90, 90, 135 degrees. The macro below FTs all slices, then combines them to yield an edited stacked plot.

After FT but before "editing", the slices are (top to bottom):

CH₂ inverted, CH and CH₃ up (final pulse = 135)

CH only (final pulse = 90)

CH only (final pulse = 90)

all protonated carbons (final pulse = 45)

After "editing", the slices are

CH₃ only
CH₂ only
CH only
all protonated carbons

First, import the data, FT and phase the first spectrum, to determine the phase correction.

NUTSMacro edited DEPT
; for Varian std DEPT sequence
; where slices 1 thru 4 are acquired with angle of last
; pulse = 45, 90, 90, 135

; first, import arrayed data, FT 1st slice and phase

; final result is stacked plot with slices
; displayed, from top to bottom:
; CH3
; CH2
; CH
; all protonated

; macro asks for file name for imported FID array
ask filea
ga
set sl 1
set filec dept.2d

; first, FT all slices
ga bc em ft ps sc in
set filea dept.2d
ga
set sl 1
ga

; 1st slice contains all peaks positive
; multiply it by 3 and save
set am 2
al
as
set fileb dept.1
sb

; slice 4 + 1.3*slice 1 removes CH2
ga
set sl 1
ga
set am 1.3
al
set sl 4
ga
as

; slice 2 minus this leaves only CH3
; but inverted
set pa 180
set am -1
al
set sl 2
ga
as
set fileb dept.4
pc
sb

; slice 3 minus 2*slice 4 eliminates CH peaks,
; leaves CH2 up, CH3 down
ga
set sl 4
ga
set am -2
al
set sl 3
ga
as

; now add this to inverted CH3 only
set am 1
al 
set sl 1
set fileb dept.4
gb
as
set fileb dept.3
sb

; save 2 x slice 2 for CH only
set filea dept.2d
ga
set sl 2
ga
al
as
set fileb dept.2
sb

; finally, combine edited slices into 2D file
set filea dept.1
set filec e_dept.2d
ga
ga sc in
set filea e_dept.2d
ga 
ss
mf
set ac .5
ac
set spplotx 0
set spploty 2
sp

end